//------------------------------------------------------------------------------------------------------------------------
// Fire burning on the floor
//
// Based on Afrit's firewall from ZDoom Monster Pack
// Afrit (and the firewall in particular) - by Nanami
//------------------------------------------------------------------------------------------------------------------------
Actor Satanic_Fire
{
    Scale			2.5
    Speed			0
    Damage			1
	ExplosionDamage	16
	ExplosionRadius	64
	    
	RenderStyle	Add
    DamageType	Fire
	Alpha		0.5
    
    DeathSound "Satanic/Miscellaneous/Flame"
	
	+STRIFEDAMAGE
	+NOCLIP
    +MISSILE
    +DROPOFF
    +RANDOMIZE
	+BLOODLESSIMPACT 

    States
    {
	Spawn:
		NULL A 8
		FRTF A 0 A_Jump(128,2)	
		FRTF A 3 Bright Light ("firelight") A_CustomMissile("Satanic_HellfireDeviceBoltSecondary",Random(0,64),0,Random(-360,360),0,0)
		FRTF BC 3 BRIGHT Light ("firelight") 
		FRTF C 0 A_Jump(191,4)
		FRTF C 0 A_CustomMissile("Satanic_Fire", 0, 24, 0)
		FRTF C 0 A_CustomMissile("Satanic_Fire", 0, 0, 0)
		FRTF C 0 A_CustomMissile("Satanic_Fire", 0, -24, 0)
		FRTF DEFGHIJKLMNO 2 Bright Light ("firelight") A_Detonate
		FRTF O 0 A_Scream
		Stop
	}
}

Actor Satanic_FireSpreader
{
    Speed	1
    Damage	0
	
	+NOCLIP
    +MISSILE
    +DROPOFF
	+BLOODLESSIMPACT 
	
    States
    {
	Spawn:
		NULL A 5 A_CustomMissile("Satanic_Fire", 0, 0, 0)
		NULL A 5 A_CustomMissile("Satanic_Fire", 0, 16, 0)
		NULL A 5 A_CustomMissile("Satanic_Fire", 0, -16, 0)
		Stop
	}
}

Actor Satanic_FireStarter
{
    Speed 		2
    Damage 		0
    DeathSound	"Satanic/Miscellaneous/Flame"
	 
	-SOLID
	+NOBLOCKMAP
    +MISSILE
    +DROPOFF
	+BLOODLESSIMPACT 
	 
    States
    {
	Spawn:
		NULL A 1
		Loop
			
	Death:
		NULL A 0 Bright A_CustomMissile("Satanic_FireSpreader", 0, Random(-32,32), Random(-360,360))
		NULL A 0 Bright A_CustomMissile("Satanic_FireSpreader", 0, Random(-32,32), Random(-360,360))
		NULL A 0 Bright A_CustomMissile("Satanic_FireSpreader", 0, Random(-32,32), Random(-360,360))
		NULL A 0 A_Scream
		Stop
	}
}