// Changes made to this enemy: bfg attack changed to a red, bfgball-inheriting 
// actor to make it easier to see, and health cut by a third (6000 was too much 
// for something that fires BFG shots IMHO). Also, states added to allow health 
// and mana-draining. Oh, and casings added. ~amv2k9

ACTOR Satanic_Demolisher //30110
{
	Obituary "%o felt the power of the Spider-Demolisher."
	Health 4000 
	Radius 96 
	Height 100 
	Mass 1000 
	Speed 16 
	PainChance 20 
	MONSTER
	+NOTARGET
	+FLOORCLIP 
	+BOSS 
	+MISSILEEVENMORE
	+NORADIUSDMG 
	Scale 1.15
	SeeSound "monster/demsit" 
	AttackSound "DEMOer/attack" 
	PainSound "DEMOer/pain" 
	DeathSound "monster/demdth" 
	ActiveSound "DEMOer/active" 
	DropItem "Satanic_TaintedCrossAltAmmo" 256
	States 
	{ 
	Spawn: 
       DEMO AB 10 A_Look 
       Loop 
	See: 
       DEMO A 3 A_Metal 
       DEMO ABB 3 A_Chase 
       DEMO C 3 A_Metal 
       DEMO CDD 3 A_Chase 
       DEMO E 3 A_Metal 
       DEMO EFF 3 A_Chase 
       Loop 
	Missile:
       DEMO A 0 BRIGHT A_Jump (128,20)
       DEMO A 20 BRIGHT A_FaceTarget
       DEMO T 1 BRIGHT A_Playsound ("weapons/bfgf")
       DEMO T 4 BRIGHT A_FaceTarget
       DEMO T 4 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget
       DEMO U 10 BRIGHT A_CustomMissile ("DemolisherBFGBall",32,0,0)
       DEMO T 0 BRIGHT A_Jump (128,10)
       DEMO T 1 BRIGHT A_Playsound ("weapons/bfgf")
       DEMO T 4 BRIGHT A_FaceTarget
       DEMO T 4 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget
       DEMO T 5 BRIGHT A_FaceTarget 
       DEMO U 10 BRIGHT A_CustomMissile ("DemolisherBFGBall",32,0,0)
       DEMO T 0 BRIGHT A_Jump (192,1)
       Goto See
       DEMO A 20 BRIGHT A_FaceTarget
       TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,135+Random(-15,15),2,-45+Random(-15,15))
	   TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,270+Random(-15,15),2,-45+Random(-15,15))
	   DEMO G 0 BRIGHT A_SPosAttack
       TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,270+Random(-15,15),2,-45+Random(-15,15))
	   TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,135+Random(-15,15),2,-45+Random(-15,15))
	   DEMO G 4 BRIGHT A_SPosAttack
       TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,270+Random(-15,15),2,-45+Random(-15,15))
	   TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,135+Random(-15,15),2,-45+Random(-15,15))
	   DEMO H 0 BRIGHT A_SPosAttack
       TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,270+Random(-15,15),2,-45+Random(-15,15))
	   TNT1 A 0 A_CustomMissile("DemolisherCasing",32,0,135+Random(-15,15),2,-45+Random(-15,15))
	   DEMO H 4 BRIGHT A_SPosAttack
       DEMO H 1 BRIGHT A_SpidRefire 
       Goto Missile+21 
	Pain: 
       DEMO I 3 
       DEMO I 3 A_Pain 
       Goto See 
	Death: 
       DEMO J 20 Bright A_Scream 
       DEMO K 10 Bright A_NoBlocking 
       DEMO LMNOPQR 10 Bright
       DEMO S 30 
       DEMO S -1 A_BossDeath 
       Stop 
	Death.DrainMana:
		DEMO J 0 A_Scream
		DEMO J 0 A_Fall
		DEMO J 0 ACS_ExecuteAlways(779,0,48,0,0)
		DEMO JKLMNOPQR 5 A_SpawnItem("Satanic_SmokeSpawner")
		DEMO S 0 A_BossDeath
		DEMO S -1
		Stop
	Death.DrainHealthEver:	
	Death.DrainHealth:
		DEMO J 0 A_Scream
		DEMO J 0 A_Fall
		DEMO J 0 ACS_ExecuteAlways(772,0,80,0,0)
		DEMO JKLMNOPQR 5 A_SpawnItem("Satanic_SmokeSpawner")
		DEMO S 0 A_BossDeath
		DEMO S -1
		Stop
   } 
}

ACTOR DemolisherBFGBall : BFGBall replaces BFGBall
{
	//Translation "112:127=176:191"
	RenderStyle "Add"
	Alpha "1.0"
	Scale "0.80"
	States
	{
	Spawn:
		DBFG AB 4 Bright
		Loop
	Death:
		//TNT1 A 0 Radius_Quake2(0,8,17,0,512)
		DBFG C 3 BRIGHT A_BFGSpray
		DBFG DEFGH 3 BRIGHT
		Stop
	}
}

ACTOR DemolisherBFGExtra : BFGExtra replaces BFGExtra
{
	//Translation "112:127=176:191"
	RenderStyle "Add"
	Alpha "1.0"
	Scale "0.60"
	States
	{
	Spawn:
		DBFS A 5 Bright
		DBFS B 5 Bright
		DBFS C 5 Bright
		DBFS D 5 Bright
		DBFS E 5 Bright
		DBFS F 5 Bright
		Stop
	}
}