//------------------------------------------------------------------------------------------------------------------------
//	Raised Revenant
//  Based on the Death Incarnate from Realm 667
//------------------------------------------------------------------------------------------------------------------------
Actor Satanic_RaisedRevenant
{
	Health 	60
	Radius 	20
	Height 	56
	Mass 	100
	Speed	8
	SeeSound	"imp/sight"
	PainSound	"imp/pain"
	DeathSound	"imp/death"
	ActiveSound "imp/active"
	Painchance GhostFriend,			0
	DamageFactor GhostFriend, 		0
	DamageFactor NoDamage,	 		0
	DamageFactor DrainHealthEver,		0
	DamageFactor DrainHealth,		0
	DamageFactor DrainMana,			0
	DamageFactor Posession, 		0
	PainChance 200
	ReactionTime 4
	RenderStyle	Translucent
	Alpha 		0.7
	MONSTER
	+NOCLIP
	+FLOORCLIP
	+FLOATBOB
	+FRIENDLY
	+MISSILEMORE
	+MISSILEEVENMORE
	Obituary	"%o was slain by his minion."
	States
	{
	Spawn:
	See:
		INCA AAA 1 A_Chase
		INCA A 0 A_SpawnItem("Satanic_RaisedRevenantGhostA")
		INCA BBB 1 A_Chase
		INCA B 0 A_SpawnItem("Satanic_RaisedRevenantGhostB")
		INCA CCC 1 A_Chase
		INCA C 0 A_SpawnItem("Satanic_RaisedRevenantGhostC")
		INCA DDD 1 A_Chase
		INCA D 0 A_SpawnItem("Satanic_RaisedRevenantGhostD")
		Loop
	Missile:
		INCA J 15 A_FaceTarget
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, -160) 
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, -120) 
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, -80) 
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, -40) 
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, 0) 
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, 40) 
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, 80)
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, 120)
		INCA J 0 A_CustomMissile ("Satanic_RaisedRevenantProjectile", 0, 0, 160)
		INCA K 15 A_FaceTarget
		Goto See
	Pain:
		INCA L 5
		INCA L 5 A_Pain
		Goto See
	Death.DrainHealth:
	Death.DrainMana:
	Burn:	
	XDeath:
	Death:
		INCA LM 3
		INCA N 3 A_Scream
		INCA O 3 A_NoBlocking
		INCA P 3
		INCA Q 3
		Stop
	}
}

Actor Satanic_RaisedRevenantProjectile
{
	Radius 	6
	Height 	8
	Speed 	8
	Damage 	4
	RenderStyle	Translucent
	Alpha 		0.5
	SeeSound "imp/attack"
	DeathSound "imp/shotx"
	DamageType DrainHealth
	PROJECTILE
	+SEEKERMISSILE
	+RANDOMIZE
	+FLOORHUGGER
	+RIPPER
	Decal DoomImpScorch
	States
	{
	Spawn: 
		INCA A 2 A_SeekerMissile (0,6)
		INCA A 0 A_SpawnItem("Satanic_RaisedRevenantGhostA")
		INCA B 2 A_SeekerMissile (0,6)
		INCA B 0 A_SpawnItem("Satanic_RaisedRevenantGhostB")
		INCA C 2 A_SeekerMissile (0,6)
		INCA C 0 A_SpawnItem("Satanic_RaisedRevenantGhostC")
		INCA D 2 A_SeekerMissile (0,6)
		INCA D 0 A_SpawnItem("Satanic_RaisedRevenantGhostD")
		Loop
	Death:
		INCA A 1
		Stop	
	}
}

Actor Satanic_RaisedRevenantGhostA
{
	Radius	4
	Height	8
	Speed	0
	Damage	0
	Mass	75
	RenderStyle Translucent
	Alpha 0.25
	PROJECTILE
	+NOCLIP
	States
	{
	Spawn:
		INCA A 10
		Stop
	}
}

Actor Satanic_RaisedRevenantGhostB : Satanic_RaisedRevenantGhostA
{
	States
	{
	Spawn:
		INCA B 10
		Stop
	}
}

Actor Satanic_RaisedRevenantGhostC : Satanic_RaisedRevenantGhostA
{
	States
	{
	Spawn:
		INCA C 10
		Stop
	}
}

Actor Satanic_RaisedRevenantGhostD : Satanic_RaisedRevenantGhostA
{
	States
	{
	Spawn:
		INCA D 10
		Stop
	}
}