Actor Satanic_Spectre : Spectre Replaces Spectre
{	
	MissileType "Satanic_SpectreShot"
	PainChance "Turn", 255
	DamageFactor Posession, 0
	DamageFactor NoDamage,	 		0
	-FRIENDLY
	States
	{
	Spawn:
		SARG A 0 Thing_Hate(0,669,3)
		SARG AB 10 A_Look
		Goto Spawn+1
	See:
		SARG AABBCCDD 2 A_Chase
		Loop
	Melee:
		SARG EF 8 A_FaceTarget
		SARG G 8 A_MissileAttack
		Goto See
	Pain.Bludgeon:	
		SARG H 0 ThrustThing(45,15,0)
		SARG H 3
		SARG H 3 A_Pain
		Goto See
	Pain.Turn:
		TNT1 A 0 A_PlaySound("Satanic/Weapons/BellRing",CHAN_WEAPON)
		TNT1 A 0 ACS_Execute(824,0,20,0,0)
		SARG H 2
		TNT1 A 0 A_ChangeFlag("Friendly",1)
		SARG H 2 A_Pain
		Goto See
	Pain.DrainHealthEver:
		SARG H 0
		SARG H 0 ACS_ExecuteAlways(779,0,1,0,0)
		SARG H 2
    	SARG H 2 A_Pain
    	goto See		
	Death.DrainHealthEver:
	Death.DrainHealth:
	Death.DrainMana:
		SARG I 0 A_Scream
		SARG I 0 A_Fall
		SARG I 0 ACS_ExecuteAlways(779,0,6,0,0)
		SARG IJKLM 5
		SARG N -1
		Stop
	Death.DemonFire:
	Burn:
		SARB I 0 A_Scream
		SARB I 0 A_Fall
		SARB I 0 A_CustomMissile("Satanic_HellfireDeviceBoltSecondary",Random(0,64),0,Random(-360,360),0,0)
		SARB I 0 A_CustomMissile("Satanic_HellfireDeviceBoltSecondary",Random(0,64),0,Random(-360,360),0,0)
		SARB I 0 A_CustomMissile("Satanic_HellfireDeviceBoltSecondary",Random(0,64),0,Random(-360,360),0,0)
		SARB I 0 A_CustomMissile("Satanic_HellfireDeviceBoltSecondary",Random(0,64),0,Random(-360,360),0,0)
		SARB I 0 A_CustomMissile("Satanic_HellfireDeviceBoltSecondary",Random(0,64),0,Random(-360,360),0,0)
		SARB I 0 A_CustomMissile("Satanic_FireStarter",6,Random(-20,20),Random(-360,360),0)         
		SARB I 0 A_CustomMissile("Satanic_FireStarter",6,Random(-20,20),Random(-360,360),0)   
		SARB IJKLM 5
		SARB NNNNNNNNN 4 A_SpawnItem("Satanic_SmokeSpawner")
		Stop
	Raise:
		SARG M 1
		SARG M 1 A_SetInvulnerable
		SARG M 1 A_UnsetSolid
		SARG M 1 A_UnsetShootable
		SARG M 1 ACS_ExecuteAlways(788,0,0,0,0)
		SARG M 1
		Stop
	Raise_Spirit:
		SARG MLKJ 6
		SARG J 0 A_SpawnItem("Satanic_RaisedImp")
		Stop
	Raise_ManaRitual:
		SARG M 4
		SARG L 4
		SARG L 4 A_SpawnItem("Satanic_HealthSpirit")
		SARG L 4 ACS_ExecuteAlways(779,0,10,0,0)
		SARG L 4 A_SpawnItem("Satanic_HealthSpiritExplosion")
		SARG M 4
		Stop
	}
}

Actor Satanic_SpectreShot
{
	Speed 16
	Height 2
	Radius 4
	Mass 19
	Damage 1
	DamageType DrainManaSpectre
	PROJECTILE
	+RIPPER
	+STRIFEDAMAGE
	States
	{
	Spawn:
		NONE A 4
		Stop	
	Death: 
		NONE A 0
		Stop
    }
}

ACTOR Runner_Spectre : Satanic_Spectre
{
	DropItem "HeartHealth" 16
}