ACTOR Satanic_TaintedCross : Weapon
{
	+ALT_AMMO_OPTIONAL
	+CHEATNOTWEAPON
	Scale 0.85
	Weapon.AmmoType1 "Satanic_SoulAmmo"
	Weapon.AmmoUse1 1
	Weapon.AmmoGive1 40
	Weapon.AmmoType2 "Satanic_TaintedCrossAltAmmo"
	Weapon.AmmoUse2 4
	Tag "Tainted Cross"
	Inventory.PickupMessage "the tainted cross binds itself to your life force."
	States
	{
	Spawn:
		TCRS P -1
		Stop
	Select:
		TNT1 A 0 A_JumpIfInventory("PWCIsOff",1,"DefXHair")
		TNT1 A 0 A_SetCrosshair(25)
		Goto SeleLoop
	DefXHair:	
		TNT1 A 0 A_SetCrosshair(0)
	SeleLoop:
		TNT1 A 0 A_Raise
		TCRS A 1 A_Raise
		Loop
	Deselect:
		TNT1 A 0 A_Lower
		TCRS A 1 A_Lower
		Loop
	Ready:
		TCRS A 1 A_WeaponReady
		Loop
	Fire:
		TCRF A 4
	Hold:	
		TCRF B 4 A_FireBullets(2,2,-1,5,"CrossSpiritPuff")
		TNT1 A 0 A_Refire
		TCRF A 4
		Goto Ready
	Altfire:
		TNT1 A 0 A_JumpIfInventory("Satanic_TaintedCrossAltAmmo",4,"AltfireEnoughCubeAmmo")
		TNT1 A 0 ACS_ExecuteAlways(769,0,40,0,0)
	AltfireEnoughCubeAmmo:	
		TCRS BBCCCDDDDEEEEEFFFFF 1
		TCRS F 1 BRIGHT A_FireCustomMissile("CrossAltfireProjectile")
		Goto Ready
	}
}

ACTOR CrossSpiritPuff
{
	+PUFFONACTORS
	+NOINTERACTION
	RenderStyle "Add"
	Alpha 0.80
	Scale 0.25
	DeathSound "tcspiritdie"
	States
	{
	Spawn:
		TCSP E 3 BRIGHT
		TCSP F 3 BRIGHT A_Scream
		TCSP GHIJ 3 BRIGHT
		Stop
	}
}

ACTOR CrossAltfireProjectile : HolyMissile
{
	Scale 0.50
	Speed 20
	States
	{
	Spawn:
		AGFX A 2 BRIGHT
		TNT1 A 0 A_SpawnItemEx("CrossAltfireProjectileTrail")
		Loop
	Death:
		TNT1 A 0 A_CHolyAttack2
		AGFX GHIJKL 5 BRIGHT
		Stop
	}
}

ACTOR CrossAltfireProjectileTrail
{
	+NOINTERACTION
	Scale 0.75
	Alpha 0.90
	RenderStyle Add
	States
	{
	Spawn:
		AGFX B 2 Bright A_FadeOut(0.075)
		TNT1 A 0 A_SetScale(0.77)
		AGFX C 2 Bright A_FadeOut(0.075)
		TNT1 A 0 A_SetScale(0.79)
		AGFX D 2 Bright A_FadeOut(0.075)
		TNT1 A 0 A_SetScale(0.81)
		AGFX E 2 Bright A_FadeOut(0.075)
		TNT1 A 0 A_SetScale(0.83)
		AGFX F 2 Bright A_FadeOut(0.075)
		Stop
	}
}
	
ACTOR CrossAltfireSpirit : HolySpirit replaces HolySpirit
{
	DamageType "DrainHealth"
	States
	{
	Spawn:
		WSPR AAB 2 BRIGHT A_CHolySeek
		WSPR B 2 BRIGHT A_CHolyCheckScream
		Loop
	Death:
		WSPR E 4 BRIGHT A_Scream
		WSPR FGHI 4 BRIGHT
		Stop
	}
}
